'=========================================================================
'【ファイル】check.vbs 補正９指数による下級条件有力馬チェック処理 
'【機能仕様】新馬・未勝利・５００万条件で補正９指数が９３以上で
'            １着以外の馬をチェック馬として登録する。
'【補    足】補正９指数は１０００条件で勝てるレベルを１００としている。
'            下級条件で１００に近い馬は１０００万条件級の能力を持って
'            おりに今回負けても次走に勝てる能力を持ている
'【開発来歴】Ver 1.00  2002.12.07  蛸坊主  
'==<入出力制御定数>=======================================================
Const ForReading  = 1, ForWriting = 2
'==<ファイル名>===========================================================
Const KAISAI_FILE   = "D:\check\kaisai.txt"     '抽出する開催成績
Const SEISEKI_CSV   = "D:\check\seiseki.csv"    '開催成績出力
Const CHECK_UMA_LST = "D:\check\check_uma.lst"  'チェック馬リスト
'==<チェック馬のマーク記号>===============================================
Const CHECK_MARK    = "1"
'==<開催成績ＣＳＶ形式のデータ項目位置　実際の位置−１を定義>=============
Const CLASS_CODE  = 8    'クラスコード
Const HOSEI_TIME  = 27   '補正９値
Const ENTRY_NO    = 37   '血統登録番号
Const YY          = 0    '開催年
Const MM          = 1    '開催月
Const DD          = 2    '開催日
Const CYAKU       = 21   '入線着順
'==<コントロールオブジェクトの定義>========================================
Set WshShell = WScript.CreateObject("WScript.Shell")
Set Aix = WScript.CreateObject("AutoItX.Control")
'====<TARGET起動>=========================================================
WshShell.Run "E:\target\FRONTIER\FRONTIER.EXE" : CRT_CHECK("TARGET")
'====<開催成績ファイル作成>===============================================
WshShell.SendKeys "%ZO" : WScript.Sleep 100
CRT_CHECK("開催成績CSV出力")
WshShell.SendKeys "{UP}{UP}{UP}{ENTER}"           : WScript.Sleep 100
CRT_CHECK("開催成績選択")
WshShell.SendKeys "{LEFT}{ENTER}"                 : WScript.Sleep 100
CRT_CHECK("開催リストファイル選択")
Aix.ClipPut (KAISAI_FILE)
WshShell.SendKeys "^v{ENTER}"                     : WScript.Sleep 100
CRT_CHECK("開催成績選択")
WshShell.SendKeys "{RIGHT}{ENTER}"                : WScript.Sleep 100
CRT_CHECK("開催成績CSV出力")
Aix.ClipPut (SEISEKI_CSV)
WshShell.SendKeys "F^v{ENTER}"                    : WScript.Sleep 100
WshShell.SendKeys "{TAB}{TAB}{TAB}{TAB}{ENTER}"   : WScript.Sleep 100
CRT_CHECK("同名ファイル処理選択")
WshShell.SendKeys "{TAB}{ENTER}"                  : WScript.Sleep 100
WAIT_CRT_CHECK("しばらくお待ちください")
CRT_CHECK("開催成績CSV出力")
WshShell.SendKeys "{DOWN}{ENTER}"                 : WScript.Sleep 100
'====<TARGETの終了>=================================================
CRT_CHECK("TARGET")
WshShell.SendKeys "^{F12}" : WScript.Sleep 100
'====<チェック馬作成処理>=================================================
Set FS        = CreateObject("Scripting.FileSystemObject")
Set CSV       = FS.OpenTextFile(SEISEKI_CSV, ForReading)
Set FSOUT     = CreateObject("Scripting.FileSystemObject")
Set LST       = FSOUT.OpenTextFile(CHECK_UMA_LST, ForWriting, True)
'<実行日の日付文字列を作成
TO_YY = DatePart("yyyy" , Date) : TO_YY = Right(TO_YY, 2)
TO_MM = DatePart("m"    , Date) : TO_MM = "0" & TO_MM : TO_MM = Right(TO_MM, 2)
TO_DD = DatePart("d"    , Date) : TO_DD = "0" & TO_DD : TO_DD = Right(TO_DD, 2)
TO_DAY = TO_YY & TO_MM & TO_DD 
'開催成績ＣＳＶをレコード単位に読み込み、チェック処理を行う
Do While CSV.AtEndOfStream <> True
   REC = CSV.ReadLine
   '読み込んだレコードをカンマで分割して配列に格納する
   CSV_ITEM = Split(REC, ",", -1, 1)
   'チェック馬の条件に該当した馬をチェック馬リストに登録する
   If CSV_ITEM(CLASS_CODE) < 39  And _
      CSV_ITEM(HOSEI_TIME) > 93  And _
      CSV_ITEM(CYAKU) > 1 Then
      'チェック馬レコードを組み立てる
      OUT_REC = ""
      OUT_REC = CSV_ITEM(ENTRY_NO) & TO_DAY & CHECK_MARK
      OUT_REC = OUT_REC & CSV_ITEM(YY) & "年" & CSV_ITEM(MM) & "月" & CSV_ITEM(DD) & "日"
      OUT_REC = OUT_REC & "に好走実績あり"
      LST.WriteLine OUT_REC
   End If
   Erase CSV_ITEM 
Loop
CSV.Close
LST.Close
'====<スクリプトの終わり>=================================================
Msgbox "補正９指数による下級条件有力馬チェック処理終了"
WScript.Quit (0)
'====<画面表示チェック関数>===============================================
Function CRT_CHECK(msg)
  TimeOut=100
  Do
    WScript.Sleep 100
    Flg = WshShell.AppActivate(msg)
    If Flg = True Then
      Exit Do
    Else 
      TimeOut = TimeOut - 1
      If TimeOut < 0 Then
        Msgbox msg & "が見つかりません" : WScript.Quit (1)
      End If
    End If
  Loop
End Function

'====<画面表示チェック２関数>===============================================
Function WAIT_CRT_CHECK(msg)
  TimeOut=100
  Do
    WScript.Sleep 1000
    Flg = WshShell.AppActivate(msg)
    If Flg = False Then
      Exit Do
    Else 
      TimeOut = TimeOut - 1
      If TimeOut < 0 Then
        Msgbox msg & "が終わりません" : WScript.Quit (1)
      End If
    End If
  Loop
End Function