(* txt2xhtml v.3.01
 * writen: Sasaki Atsushi <mailto:hm7@mac.com>
 * last modified: 2004-05-05T12:39:51+09:00
 *)

set dfltDlm to AppleScript's text item delimiters
set getTime to load script file ((path to scripts folder) & "lib:getTime.scpt" as string)
set pad to load script file ((path to scripts folder) & "lib:pad.scpt" as string)
set crrDate to current date
tell getTime to set {monAbbr, monNum, d} to {getMon(crrDate, string), getMon(crrDate, number), day of crrDate}
set artDate to monAbbr & ". " & d & ". " & year of crrDate as string
tell pad to set {monNum, d} to {pad(monNum, 2), pad(d, 2)}
set artId to "w" & year of crrDate & "." & monNum & "." & d & "-00" as string

set rp to load script file ((path to scripts folder) & "lib:rp.scpt" as string)
-- set safeSGMLchar to load script file ((path to scripts folder) & "lib:html:safeSGMLchar.scpt" as string)


tell application "Jedit4"
	activate
	tell document 1
		if html coloring then
			display dialog "This document may be already HTML.  If you want to make a HTML doc anyway, turn off HTML coloring." buttons {"Continue", "Done"} default button "Done" with icon stop
			if button returned of result is "Done" then return false
		end if
		try
			inhibit redraw
			set selection to paragraphs 1 thru -1
			set txt to selection
			-- tell safeSGMLchar to set txt to safeSGMLchar(txt)
			set AppleScript's text item delimiters to return & return
			set txt to every text item of txt as list
			set h to "<h2>" & item 1 of txt & "</h2>"
			set txt to rest of txt
			repeat with e in txt
				if e begins with tab & "o " then
					set contents of e to "<ul>" & return & e & "</li>" & return & "</ul>"
					tell rp to set contents of e to rp(e, tab & "o ", "</li>" & return & tab & "<li>")
					tell rp to set contents of e to rp(e, "<ul>" & return & "</li>", "<ul>")
				else
					set contents of e to "<p>" & e & "</p>"
				end if
			end repeat
			set AppleScript's text item delimiters to return
			set selection to h & return & (txt as string)
			set selection to before paragraph 1
			repeat
				find "<\\s*[^/][^>]*>[^<]+<\\s*/[^>]*>" in it with grep without start at top and wrap around
				if not result then exit repeat
				remove break selection
			end repeat
			replace "{[！？。!?]}{[^<^)^」]}" to "\\1" & return & tab & "\\2" in it with grep -- 句点の直後は改行
			replace "\\[\\[{[^:]+}:{[^\\]]+}\\]\\]" to "<a href=\"\\2\">\\1</a>" in it with grep -- hyperlinks
			replace "<h2>{[^>]+}</h2>" to "<h2 xml:lang=\"en\"><a href=\"#" & artId & "\">\\1</a></h2>" in it with grep
			replace "^" to tab in it with grep -- indent
			insert "<!-- Article -->" & return & "<div class=\"content\" id=\"" & artId & "\">" & return at before paragraph 1
			insert return & tab & "<div class=\"date\">" & artDate & "</div>" & return & "</div>" & return at after paragraph -1
			replace "^" to tab & tab & tab in it with grep
			replace "{[\\h8140-\\h9fff\\he040-\\hfcff]}{[\\h20-\\hff]}" to "\\1 \\2" in it with grep
			replace "{[\\h20-\\hff]}{[\\h8140-\\h9fff\\he040-\\hfcff]}" to "\\1 \\2" in it with grep
			replace "( {[\\h8140-\\h9fff\\he040-\\hfcff]}" to "(\\1" in it with grep
			replace "{[\\h8140-\\h9fff\\he040-\\hfcff]} )" to "\\1)" in it with grep
			replace "{[\\h8140-\\h9fff\\he040-\\hfcff]} {<[^>]+>} {[\\h8140-\\h9fff\\he040-\\hfcff]}" to "\\1\\2\\3" in it with grep
			replace "{<\\s*[^/][^>]*>} {[\\h8140-\\h9fff\\he040-\\hfcff]}" to "\\1\\2" in it with grep
			replace "{[\\h8140-\\h9fff\\he040-\\hfcff]} {<\\s*/[^>]*>}" to "\\1\\2" in it with grep
			replace "{[\\h8140-\\h9fff\\he040-\\hfcff]} {[!?.,]}" to "\\1\\2" in it with grep
			replace "{[\\h20-\\h7e]}'{[dmst]} " to "\\1&rsquo;\\2 " in it with grep
			replace "n'{[\\s\\r<>]}" to "n&rsquo;\\1" in it with grep
			replace "\\s{[！？。!?]}" to "\\1" in it with grep -- 句点の直前のスペースを削除
			repeat
				replace tab & " " to tab in it with grep
				if result is 0 then exit repeat
			end repeat
			repeat
				replace "  " to " " in it with grep
				if result is 0 then exit repeat
			end repeat
		on error errMsg number errNum
			set AppleScript's text item delimiters to dfltDlm
			allow redraw
			display dialog "txt2xhtml: " & errMsg & return & "Error: #" & errNum with icon stop buttons {"OK"} default button "OK"
			return false
		end try
		set AppleScript's text item delimiters to dfltDlm
		allow redraw
		set html coloring to true
	end tell
end tell

-- EOF