<通信方法>
（１）ケーブルを買ってきて、つなぎます。
（２）PC-E650上にRAMファイルを、INIT "E:16K"命令で作ります。
（３）プログラムをRAMファイルに保存します。SAVE "E:PROG.BAS",A
PROG.BASは他の名前でもOKです。,Aは、ASCII（アスキー）形式での保存の場合です。
（４）PC-E650上に、以下のプログラムを手入力します。
（５）お互いの通信相手のプログラムを実行し、通信します。



-----------------------------------------------------




100 *T
101 'REM ﾂｳｼﾝﾖｳ ｻﾝﾌﾟﾙ ﾌﾟﾛｸﾞﾗﾑ
110 CLS :POKE &HBFD35,0,255,0,80
120 PRINT "***** ﾂｳｼﾝﾖｳ ｻﾝﾌﾟﾙ ﾌﾟﾛｸﾞﾗﾑ *****"
130 PRINT "ﾎﾝﾀｲRAM(E:)ﾆ RAMﾌｧｲﾙｦ INITﾒｲﾚｲﾃﾞ 16KB ｶｸﾎ ｼﾃｸﾀﾞｻｲ!"
140 INPUT "OK(Y)?";I$:IF I$<>"Y"THEN 140
150 CLS :PRINT "ｱｯﾌﾟﾛ-ﾄﾞ(ｿｳｼﾝ) =[U]"
152 PRINT "ﾀﾞｳﾝﾛ-ﾄﾞ(ｼﾞｭｼﾝ) =[D]"
158 INPUT I$
160 IF (I$<>"U")AND (I$<>"D")THEN 150
170 IF I$="U"THEN "U"
180 GOTO "D"
190 "U":OPEN "COM:1200,N,8,1,A,L,&1A,X,S"
200 OPEN "E:PROG.BAS"FOR INPUT AS #2
210 PRINT "ﾊﾟｿｺﾝ ｦ ﾀﾞｳﾝﾛ-ﾄﾞ(ｼﾞｭｼﾝ)ｼﾞｮｳﾀｲ ﾆ ｼﾃｸﾀﾞｻｲ!"
220 INPUT "OK(Y)?";I$:IF I$<>"Y"THEN 220
225 PRINT "--- ｿｳｼﾝﾁｭｳ ---"
230 A$=INPUT $(1,2)
240 IF EOF (2)THEN PRINT #1,CHR$ &H1A:CLOSE :PRINT :PRINT "*** ｶﾝﾘｮｳ ｼﾏｼﾀ ***":GOTO "END"
250 PRINT A$;
260 PRINT #1,A$;
270 GOTO 230
280 "D":OPEN "COM:1200,N,8,1,A,L,&1A,X,S"
290 OPEN "E:PROG.BAS"FOR OUTPUT AS #2
300 PRINT "ﾊﾟｿｺﾝ ﾖﾘ ｿｳｼﾝｼﾃ ｸﾀﾞｻｲ!"
310 A$=INPUT $(1,1):PRINT "--- ｼﾞｭｼﾝﾁｭｳ ---":GOTO 340
320 A$=INPUT $(1,1)
340 IF A$=CHR$ &H0A THEN PRINT A$;:PRINT #2,A$;:ELSE 350
345 A$=INPUT $(1,1):IF (A$=CHR$ &H0D)OR (A$=CHR$ &H1A)THEN PRINT #1,CHR$ &H0D;CHR$ &H11:CLOSE :PRINT :PRINT "*** ｶﾝﾘｮｳ ｼﾏｼﾀ ***":GOTO "LD"
350 PRINT A$;
360 PRINT #2,A$;
370 GOTO 320
400 "LD"
410 PRINT "ｼﾞｭｼﾝ ｼﾀ ﾌﾟﾛｸﾞﾗﾑ ｦ ﾖﾋﾞﾀﾞｼﾏｽｶ"
420 INPUT "OK(Y)?";I$:IF I$<>"Y"THEN "END"
430 PRINT "ﾛ-ﾄﾞ ｼﾃｲﾏｽ!!!"
440 POKE &HBFD35,2,223,4,80
450 KEY 0,"LOAD"+CHR$ 34+"E:PROG."+CHR$ 34+CHR$ 13
500 "END":POKE &HBFD35,2,223,4,80:END